Hi @ahmetg ,
Qt 6.4.3 can be integrated into our Linux BSP 6 in Yocto Project. Here are the steps.
Clone meta-qt6 in layers folder.
git clone -b 6.4.3 git://code.qt.io/yocto/meta-qt6.git
Add populate_sdk_qt6.bbclass in meta-qt6/classes
SUMMARY = "Meta package for building an installable Qt6 toolchain and SDK"
inherit populate_sdk populate_sdk_qt6_base
TOOLCHAIN_HOST_TASK:append = " nativesdk-packagegroup-qt6-toolchain-host"
TOOLCHAIN_TARGET_TASK:append = " packagegroup-qt6-modules"
FEATURE_PACKAGES_qtcreator-debug = "packagegroup-qt6-qtcreator-debug"
Create packagegroup-qt6-qtcreator-debug.bb in meta-qt6/recipes-qt/packagegroups.
SUMMARY = "Remote debugging tools for QtCreator integration"
LICENSE = "MIT"
inherit packagegroup
# Override by distro if needed
VIRTUAL-RUNTIME_qtcreator-debug-ssh-daemon ?= "openssh-sshd"
RDEPENDS:${PN} = " \
gdbserver \
${VIRTUAL-RUNTIME_qtcreator-debug-ssh-daemon} \
openssh-sftp-server \
qtdeclarative \
"
Create packagegroup-tdx-qt6.bb in meta-toradex-demos/recipes-images/images/.
SUMMARY = "Packagegroup which provides most QT6 libraries and a QT6 demo"
PACKAGE_ARCH = "${MACHINE_ARCH}"
inherit packagegroup
PROVIDES = "${PACKAGES}"
PACKAGES += " \
${PN}-fonts \
${PN}-libs \
"
RRECOMMENDS:${PN} = " \
${PN}-fonts \
${PN}-libs \
"
SUMMARY:${PN}-fonts = "Some fonts useful for QT5"
RRECOMMENDS:${PN}-fonts = " \
ttf-dejavu-common \
ttf-dejavu-sans \
ttf-dejavu-sans-mono \
ttf-dejavu-serif \
"
SUMMARY:${PN}-libs = "QT5 libraries"
RRECOMMENDS:${PN}-libs = " \
qt3d \
qtbase \
qtcharts \
qtcoap \
qtconnectivity \
qtdatavis3d \
qtdeclarative \
qtimageformats \
qtlottie \
qtmqtt \
qtmultimedia \
qtnetworkauth \
qtopcua \
qtquick3d \
qtquicktimeline \
qtremoteobjects \
qtscxml \
qtsensors \
qtserialbus \
qtserialport \
qtsvg \
qttools \
qttranslations \
qtvirtualkeyboard \
${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'qtwayland', '', d)} \
qtwebchannel \
qtwebsockets \
"
Create tdx-reference-multimedia-qt6-image.bb in meta-toradex-demos/recipes-images/images/. Delete our default tdx-reference-multimedia-image.bb as well.
require tdx-reference-minimal-image.bb
SUMMARY = "Toradex Embedded Linux Reference Multimedia Image"
DESCRIPTION = "Image for BSP verification with QT and multimedia features"
inherit populate_sdk_qt6
#Prefix to the resulting deployable tarball name
export IMAGE_BASENAME = "Reference-Multimedia-Image"
IMAGE_FEATURES += " \
${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'weston', \
bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11-base', '', d), d)} \
"
IMAGE_INSTALL += " \
packagegroup-tdx-cli \
packagegroup-tdx-graphical \
packagegroup-tdx-qt6 \
packagegroup-fsl-isp \
\
bash \
coreutils \
less \
makedevs \
mime-support \
net-tools \
util-linux \
v4l-utils \
\
gpicview \
media-files \
"
Replace meta-qt5 with meta-qt6 in build/conf/bblayers.conf. And remove unused distro feature and package from build/conf/local.conf.
DISTRO_FEATURES:remove = " directfb x11"
IMAGE_INSTALL:remove = " gpicview"
Then you can build the image by bitbake tdx-reference-multimedia-qt6-image.